Câu hỏi Đếm các tên duy nhất trong phạm vi cột excel


Tôi có một bảng tính excel có chứa một danh sách các tên máy chủ trong cột B. Tên máy chủ xuất hiện nhiều lần trong cột này.

Tôi muốn đếm số lượng tên máy chủ duy nhất trong phạm vi cho.

Phạm vi là B2:B1400

Tôi đã thử nó nhưng nó đã trả về 0

=SUM(IF(FREQUENCY(B2:B1400,B2:B1400)>0,1))

Có ai biết làm thế nào?


4
2017-12-17 10:09


gốc


Bạn luôn có thể thực hiện "xóa các mục trùng lặp" điều này sẽ cho bạn biết số lượng mục đã bị xóa
Công thức bạn đề xuất hợp lệ nhưng chỉ để tính riêng biệt số trong phạm vi - đối với văn bản hoặc số (hoặc kết hợp cả hai), bạn có thể sử dụng công thức tôi đề xuất bên dưới - barry houdini


Các câu trả lời:


TẦN SỐ không hoạt động như thế.

Một trong những cách nhanh nhất để có được số lượng riêng biệt là đầu tiên lọc ra các bản sao và sau đó chọn các bản ghi, bấm chuột phải vào thanh dưới cùng của Excel và kiểm tra 'Đếm'.

Xem bài đăng này cho nhận được các giá trị khác biệt trong Excel.


CẬP NHẬT: Có rất nhiều cách bạn có thể đạt được điều này .. http://www.get-digital-help.com/2009/03/30/how-to-extract-a-unique-list-and-the-duplicates-in-excel-from-one-column/


2
2017-12-17 10:23





Công thức này sẽ cung cấp cho bạn một "số đếm riêng biệt" mà không có bất kỳ cột trợ giúp nào

=SUMPRODUCT((B2:B1400<>"")/COUNTIF(B2:B1400,B2:B1400&""))


8
2017-12-17 15:05



Cái này hoạt động ra sao? SUMPRODUCT có một mảng 2D, phải không? (B2: B1400 <> "") tạo ra một mảng các giá trị TRUE / FALSE, nhưng toán tử phân chia đang làm gì và kết nối là gì? Đó có phải là một mẹo để có được COUNTIF để tạo ra một mảng thay vì một giá trị duy nhất? - Nick Russo
Tôi đã cố gắng giải thích cách nó hoạt động trong một câu trả lời khác ở đây: stackoverflow.com/questions/18586815/… - barry houdini


Thêm cột thứ hai với

=1/COUNTIF($B$2:$B$1400;B2)

và sau đó tổng hợp cột.

Mỗi hàng sẽ có một giá trị tương ứng với phần nhỏ của tổng số lần xuất hiện tương tự. Tổng của tất cả các hàng sẽ cung cấp cho bạn số lượng riêng biệt.


1
2017-12-17 10:35





Tôi biết điều này có thể đã được trả lời nhưng tôi đã vật lộn với điều này và thấy công thức sau đây hữu ích.

= SUM (IF (FREQUENCY (MATCH ($ A $ 2: $ A $ 14, $ A $ 2: $ A $ 14,0), MATCH ($ A $ 2: $ A $ 14, $ A $ 2: $ A $ 14,0))> 0,1))

Về cơ bản đặt công thức MATCH thay vì tham chiếu ô. Cũng tìm thấy video trên YouTube https://youtu.be/r51RdvOONRQ


1
2018-02-07 14:05





Bạn có thể sử dụng dưới đây như một mảng:

{=SUM(1/COUNTIF(B2:B1400,B2:B1400))}

Tuy nhiên, không cần bất kỳ cột trợ giúp nào, phạm vi càng lớn thì càng cần tính toán nhiều lần hơn .; nhưng điều đó đúng với công thức mảng.


0
2018-02-07 14:12